// Gradle初始化脚本(Flutter注入)
apply from: "init.gradle"
apply from: "dependencies.gradle"

allprojects { project ->
    buildscript {
        ext.flutter_io = System.env.FLUTTER_STORAGE_BASE_URL
                ?: "https://storage.googleapis.com"
        repositories {
            maven { url 'https://jitpack.io' }
        }
        dependencies {
            classpath "com.github.axen1314.lancet:lancet-plugin:$lancet_version"
        }
    }
    repositories {
        maven { url "$flutter_io/download.flutter.io" }// Flutter
    }
    project.afterEvaluate {
        if (project.name == "app") {
            Project flutterProject = project.rootProject.findProject(":flutter")
            if (flutterProject == null) {
                project.logger.error("Flutter project not found!")
            } else {
                project.apply plugin: 'me.ele.lancet'
                project.dependencies {
                    implementation (flutterProject, {
                        exclude group: 'androidx.swiperefreshlayout'
                    })
                    compileOnly "com.github.axen1314.lancet:lancet-base:$lancet_version"
                }
            }

        }
    }
}