// Top-level build file where you can add configuration options common to all sub-projects/modules.

apply from: 'dependencies.gradle'

buildscript {
    ext.kotlin_version = '1.3.72'

    repositories {
        google()
        jcenter()
        mavenCentral()
        maven { url 'https://jitpack.io' }
        maven { url "https://maven.google.com" }
        maven { url 'https://dl.bintray.com/umsdk/release' }
        maven { url "https://dl.bintray.com/thelasterstar/maven/" } //weiboSDK
        maven { url 'https://dl.bintray.com/aweme-open-sdk-team/public' } //tiktokSDK
    }

    dependencies {
        classpath "com.android.tools.build:gradle:4.1.0"
        classpath "io.sentry:sentry-android-gradle-plugin:1.7.36"
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlin_version"
        // 使用了 1.2.21 在蓝叠模拟器上无法进入首页? 但是不使用又会出现触发 V3 签名...
        classpath 'com.tencent.mm:AndResGuard-gradle-plugin:1.2.20'
    }
}

allprojects {
    repositories {
        google()
        jcenter()
        mavenCentral()
        maven { url 'https://jitpack.io' }
        maven { url "https://dl.bintray.com/thelasterstar/maven/" }//weiboSDK
        maven { url 'https://dl.bintray.com/aweme-open-sdk-team/public' } //tiktokSDK
        maven { url 'http://maven.aliyun.com/nexus/content/repositories/releases/' }
        maven { url "http://dl.bintray.com/piasy/maven" }
        maven { url 'https://dl.bintray.com/guardian/android' }
        maven { url 'https://dl.bintray.com/umsdk/release' }
    }
}

subprojects {
    subproject ->
        afterEvaluate {
            if ((subproject.plugins.hasPlugin('android') || subproject.plugins.hasPlugin('android-library'))) {
                if (!android.compileSdkVersion) {
                    android {
                        compileSdkVersion rootProject.ext.compileSdkVersion
                    }
                }
                android {
                    buildToolsVersion rootProject.ext.buildToolsVersion

                    defaultConfig {
                        minSdkVersion rootProject.ext.minSdkVersion

                        // for those defined in AndroidManifest.xml
                        manifestPlaceholders = [
                                manifestApplicationId: "${applicationId}",
                                tencentAppId         : "${TENCENT_APPID}",
                        ]
                    }
                    lintOptions.abortOnError false

                    packagingOptions {
                        exclude 'META-INF/NOTICE'
                        exclude 'META-INF/LICENSE'
                        exclude 'META-INF/DEPENDENCIES'
                        exclude 'META-INF/services/javax.annotation.processing.Processor'
                    }

                }
            }
        }
}