// Gradle初始化脚本(Flutter注入)
apply from: "init.gradle"
apply from: "dependencies.gradle"

rootProject {

    buildscript {
        ext.flutter_io = System.env.FLUTTER_STORAGE_BASE_URL
                ?: "https://storage.googleapis.com"
        repositories {
            maven { url 'https://jitpack.io' }
        }
        dependencies {
            classpath "com.github.axen1314.lancet:lancet-plugin:$lancet_version"
        }
    }

    repositories {
        maven { url "$flutter_io/download.flutter.io" }// Flutter
    }

    subprojects {
        if (name == "app") {
            afterEvaluate { project ->
                Project flutterProject = rootProject.findProject(":flutter")
                if (flutterProject == null) {
                    logger.error("Flutter project not found!")
                } else {
                    project.apply plugin: 'me.ele.lancet'
                    project.dependencies {
                        implementation (flutterProject, {
                            exclude group: 'androidx.legacy', module: "legacy-support-v4" // imei_plugin
                            exclude group: 'com.facebook.fresco', module: 'fresco'// flutter_fresco
                        })
                        compileOnly "com.github.axen1314.lancet:lancet-base:$lancet_version"
                    }
                }
            }
        }
    }
}